+Show TOC
×Hide TOC

SosTracer

Kind of class:	class
Inherits from:	none
Implements:	LogListener
Version:	1.0
Author:	Francis Bourre, Pablo Costantini
Classpath:	com.bourre.utils.SosTracer
File last modified:	Wednesday, 31 October 2007, 07:35:30

► View source

▼ Hide source

/*
 * Copyright the original author or authors.
 * 
 * Licensed under the MOZILLA PUBLIC LICENSE, Version 1.1 (the "License");
 * you may not use this file except in compliance with the License.
 * You may obtain a copy of the License at
 * 
 *      http://www.mozilla.org/MPL/MPL-1.1.html
 * 
 * Unless required by applicable law or agreed to in writing, software
 * distributed under the License is distributed on an "AS IS" BASIS,
 * WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
 * See the License for the specific language governing permissions and
 * limitations under the License.
 */

 /**
 * {@code SosTracer} uses Powerflasher SOS console
 * to log messages.
 * 
 * <p>See http://sos.powerflasher.com/english.html for
 * more informations about SOS Console.
 * 
 * <p>{@code XMLSocket} protocol is used for Pixlib /
 * SOS Console communication.
 * 
 * <p>Implements {@link LogListener} interface to listen to 
 * {@link com.bourre.log.Logger} events.
 * 
 * <p>Example
 * <code>
 *   Logger.getInstance().addLogListener( SosTracer.getInstance() );
 *   PixlibDebug.INFO( "Logging API ready" );
 * </code>
 * 
 * @author Francis Bourre
 * @author Pablo Costantini
 * @version 1.0
 */

import com.bourre.commands.Delegate;
import com.bourre.data.collections.Map;
import com.bourre.log.LogEvent;
import com.bourre.log.LogLevel;
import com.bourre.log.LogListener;
import com.bourre.log.PixlibStringifier;

class com.bourre.utils.SosTracer
    implements LogListener
{
    //-------------------------------------------------------------------------
    // Private properties
    //-------------------------------------------------------------------------
    
    private static var _oInstance:SosTracer;
    
    private var _oXMLSocket:XMLSocket;
    private var _bIsConnected:Boolean;
    private var _aBuffer:Array;
    private var _mFormat : Map;
    
    
    //-------------------------------------------------------------------------
    // Public Properties
    //-------------------------------------------------------------------------
    
    /** SOS console IP Address. **/
    public static var IP:String = "localhost";
    
    /** SOS console communication port. **/
    public static var PORT:Number = 4445;
    
    
    public static var DEBUG_FORMAT:String = "DEBUG_FORMAT";
    public static var INFO_FORMAT:String = "INFO_FORMAT";
    public static var WARN_FORMAT:String = "WARN_FORMAT";
    public static var ERROR_FORMAT:String = "ERROR_FORMAT";
    public static var FATAL_FORMAT:String = "FATAL_FORMAT";
    
    public static var DEBUG_KEY:String = '<setKey><name>' + SosTracer.DEBUG_FORMAT + '</name><color>' + 0x1394D6 + '</color></setKey>\n';
    public static var INFO_KEY:String = '<setKey><name>' + SosTracer.INFO_FORMAT + '</name><color>' + 0x12C9AC + '</color></setKey>\n';
    public static var WARN_KEY:String = '<setKey><name>' + SosTracer.WARN_FORMAT + '</name><color>' + 0xFFCC00 + '</color></setKey>\n';
    public static var ERROR_KEY:String = '<setKey><name>' + SosTracer.ERROR_FORMAT + '</name><color>' + 0xFF6600 + '</color></setKey>\n';
    public static var FATAL_KEY:String = '<setKey><name>' + SosTracer.FATAL_FORMAT + '</name><color>' + 0xFF0000 + '</color></setKey>\n';
    
    
    //-------------------------------------------------------------------------
    // Public API
    //-------------------------------------------------------------------------
    
    /**
     * Returns {@code SosTracer} instance.
     * 
     * <p>Always return the same instance.
     * 
     * @return {@code SosTracer} instance
     */
    public static function getInstance() : SosTracer
    {
        if (!SosTracer._oInstance) SosTracer._oInstance = new SosTracer();
        return SosTracer._oInstance;
    }

    /**
     * Clears SOS console.
     */
    public function clearOutput() : Void
    {
        _oXMLSocket.send( "<clear/>\n" );
    }
    
    /**
     * 
     */
    public function getFoldMessage( sTitre : String, sMessage : String, level : LogLevel ) : String
    {
        var s:String = "";
        s += '<showFoldMessage key="' + _mFormat.get( level ) + '">';
        s += '<title>' + sTitre + '</title>';
        s += '<message>' + sMessage + '</message></showFoldMessage>';
        return s;
    }
    
    /**
     * Sends message to SOS Console.
     * 
     * <p>If communication with console is not ready,
     * messages are buffered.
     * 
     * <p>Buffered messages are send to console when connection is
     * established.
     *  
     * @param o Log message
     * @param level A {@link com.bourre.log.LogLevel} instance
     */
    public function output( o, level : LogLevel ) : Void
    {
        var sLevel : String = level? _mFormat.get( level ) : SosTracer.DEBUG_FORMAT;
        
        var s:String = getFoldMessage    (
                                            unescape( String(o) ), 
                                            level.getName() + ' - [' + getTimer() + ']' + String(o),
                                            level
                                        );
        if (_bIsConnected)
        {
            _output( s );
            
        } else
        {    
            _buffer( s );
        }
    }
    
    /**
     * {@code Unity2} specific callbacks
     * 
     * <p>Sends message to console
     * 
     * @param o
     * @param infoObj Log info message
     */
    public function update(o, infoObj) : Void
    {
        output((infoObj.getLevel() + ": ") + infoObj.getMessage());
    }
    
    /**
     * {@link com.bourre.log.LogListener} callback implementation.
     * 
     * <p>{@link com.bourre.log.Logger} dispatches {@code onLog}
     * event when messages are send to logging API.
     * 
     * @param e A {@link com.bourre.log.LogEvent} instance.
     */
    public function onLog( e:LogEvent ) : Void
    {
        output( e.content, e.level );
    }
    
    /**
     * Returns the string representation of this instance.
     * @return the string representation of this instance
     */
    public function toString() : String 
    {
        return PixlibStringifier.stringify( this );
    }
    
    
    //-------------------------------------------------------------------------
    // Private implementation
    //-------------------------------------------------------------------------
    
    /**
     * Constructs a new {@code SosTracer} instance.
     * 
     * <p>Constructor is private, use {@link #getInstance}
     * method to instanciate {@code SosTracer} class.
     */
    private function SosTracer()
    {
        _aBuffer = new Array();
        
        _buildColorKeys();
        
        _oXMLSocket = new XMLSocket();
        _oXMLSocket.onConnect = Delegate.create(this, _onConnect);
        _oXMLSocket.connect (SosTracer.IP, SosTracer.PORT);
    }
    
    /**
     * Builds some pre-defined formats for logging messages.
     */
    private function _buildColorKeys() : Void
    {
        _mFormat = new Map();

        _mFormat.put( LogLevel.DEBUG, SosTracer.DEBUG_FORMAT );
        _mFormat.put( LogLevel.INFO, SosTracer.INFO_FORMAT );
        _mFormat.put( LogLevel.WARN, SosTracer.WARN_FORMAT );
        _mFormat.put( LogLevel.ERROR, SosTracer.ERROR_FORMAT );
        _mFormat.put( LogLevel.FATAL, SosTracer.FATAL_FORMAT );
        
        _buffer( SosTracer.DEBUG_KEY );
        _buffer( SosTracer.INFO_KEY );
        _buffer( SosTracer.WARN_KEY );
        _buffer( SosTracer.ERROR_KEY );
        _buffer( SosTracer.FATAL_KEY );
    }
    
    
    /**
     * Adds passed-in {@code s} message to buffer.
     * 
     * <p>Only use console is not already connected.
     */
    private function _buffer( s:String ) : Void
    {
        _aBuffer.push( s );
    }
    
    /**
     * Sends message to console.
     * 
     * @param s Message string
     */
    private function _output( s:String ) : Void
    {
        _oXMLSocket.send( s );
    }
    
    /**
     * {@code XmlSocket} callback
     * 
     * <p>Calls when connection with SOS Console
     * is established.
     */
    private function _onConnect() : Void
    {
        _emptyBuffer();
        _bIsConnected = true;
    }
    
    /**
     * Sends all buffered messages to console.
     */
    private function _emptyBuffer() : Void
    {
        var l:Number = _aBuffer.length;
        for (var i:Number = 0; i<l; i++) _output( _aBuffer[i] );
    }
    
}

SosTracer uses Powerflasher SOS console
to log messages.

See http://sos.powerflasher.com/english.html for
more informations about SOS Console.

XMLSocket protocol is used for Pixlib /
SOS Console communication.

Implements com.bourre.log.LogListener interface to listen to
com.bourre.log.Logger events.

Example

Logger.getInstance().addLogListener( SosTracer.getInstance() );
PixlibDebug.INFO( "Logging API ready" );

Summary

Class properties

IP
PORT
DEBUG_FORMAT
INFO_FORMAT
WARN_FORMAT
ERROR_FORMAT
FATAL_FORMAT
DEBUG_KEY
INFO_KEY
WARN_KEY
ERROR_KEY
FATAL_KEY

Class methods

getInstance

Instance methods

clearOutput
getFoldMessage
output
update
toString

Event handlers

onLog

Class properties

DEBUG_FORMAT

static DEBUG_FORMAT:String = "DEBUG_FORMAT"

(read,write)

DEBUG_KEY

static DEBUG_KEY:String = '' + SosTracer.DEBUG_FORMAT + '' + 0x1394D6 + '\n'

(read,write)

ERROR_FORMAT

static ERROR_FORMAT:String = "ERROR_FORMAT"

(read,write)

ERROR_KEY

static ERROR_KEY:String = '' + SosTracer.ERROR_FORMAT + '' + 0xFF6600 + '\n'

(read,write)

FATAL_FORMAT

static FATAL_FORMAT:String = "FATAL_FORMAT"

(read,write)

FATAL_KEY

static FATAL_KEY:String = '' + SosTracer.FATAL_FORMAT + '' + 0xFF0000 + '\n'

(read,write)

INFO_FORMAT

static INFO_FORMAT:String = "INFO_FORMAT"

(read,write)

INFO_KEY

static INFO_KEY:String = '' + SosTracer.INFO_FORMAT + '' + 0x12C9AC + '\n'

(read,write)

IP

static IP:String = "localhost"

(read,write)

SOS console IP Address.

PORT

static PORT:Number = 4445

(read,write)

SOS console communication port.

WARN_FORMAT

static WARN_FORMAT:String = "WARN_FORMAT"

(read,write)

WARN_KEY

static WARN_KEY:String = '' + SosTracer.WARN_FORMAT + '' + 0xFFCC00 + '\n'

(read,write)

Class methods

getInstance

static function getInstance (

) : SosTracer

Returns SosTracer instance.

Always return the same instance.

Returns:

SosTracer instance

Instance methods

clearOutput

function clearOutput (

) : Void

Clears SOS console.

getFoldMessage

function getFoldMessage (

sTitre:String, sMessage:String, level:LogLevel) : String

output

function output (

level:LogLevel) : Void

Sends message to SOS Console.

If communication with console is not ready,
messages are buffered.

Buffered messages are send to console when connection is
established.

Parameters:

o :

Log message

level:

A com.bourre.log.LogLevel instance

toString

function toString (

) : String

Returns the string representation of this instance.

Returns:

the string representation of this instance

update

function update (

) : Void

Unity2 specific callbacks

Sends message to console

Parameters:

o :

infoObj:

Log info message

Event handlers

onLog

function onLog (

e:LogEvent) : Void

com.bourre.log.LogListener callback implementation.

com.bourre.log.Logger dispatches onLog
event when messages are send to logging API.

Parameters:

A com.bourre.log.LogEvent instance.

Specified by:

com.bourre.log.LogListener.onLog