+Show TOC
×Hide TOC

TweenMS

Kind of class:	class
Inherits from:	BasicTweenMS < AbstractTween
Implements:	ITween
Version:	1.0
Author:	Francis Bourre
Classpath:	com.bourre.transitions.TweenMS
File last modified:	Wednesday, 31 October 2007, 07:35:30

► View source

▼ Hide source

/*
 * Copyright the original author or authors.
 * 
 * Licensed under the MOZILLA PUBLIC LICENSE, Version 1.1 (the "License");
 * you may not use this file except in compliance with the License.
 * You may obtain a copy of the License at
 * 
 *      http://www.mozilla.org/MPL/MPL-1.1.html
 * 
 * Unless required by applicable law or agreed to in writing, software
 * distributed under the License is distributed on an "AS IS" BASIS,
 * WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
 * See the License for the specific language governing permissions and
 * limitations under the License.
 */
 
 /**
 * {@code TweenMS} extends {@link BasicTweenMS} class implementing
 * Pixlib Event API.
 * 
 * <p>Can use these methods to control Tween event :
 * <ul>
 *   <li>{@link #addListener}</li>
 *   <li>{@link #removeListener}</li>
 *   <li>{@link #addEventListener}</li>
 *   <li>{@link #removeEventListener}</li>
 * </ul>
 * 
 * <p>Example
 * <code>
 *   var t : TweenMS = new TweenMS(mc, '_alpha', 0, 2000, 100);
 *   t.addListener(this);
 *   t.addEventListener(TweenMS.onMotionFinishedEVENT, this, __onFinish);
 *   t.start();
 * </code>
 * 
 * @author Francis Bourre
 * @version 1.0
 */

import com.bourre.events.EventBroadcaster;
import com.bourre.events.IEvent;
import com.bourre.log.PixlibStringifier;
import com.bourre.transitions.BasicTweenMS;
import com.bourre.transitions.ITween;
import com.bourre.transitions.ITweenListener;
import com.bourre.transitions.TweenEvent;
import com.bourre.transitions.TweenEventType;

class com.bourre.transitions.TweenMS extends BasicTweenMS 
    implements ITween
{
    //-------------------------------------------------------------------------
    // Events definition
    //-------------------------------------------------------------------------
    
    /**
     * Broadcasted to listeners when tween starts.<br>
     */
    [Event("onStart")]
    public static var onStartEVENT:TweenEventType = TweenEventType.onStartEVENT;
    
    /**
     * Broadcasted to listeners when tween stops.<br>
     */
    [Event("onStop")]
    public static var onStopEVENT:TweenEventType = TweenEventType.onStopEVENT;
    
    /**
     * Broadcasted to listeners when tween is finished.<br>
     */
    [Event("onMotionFinished")]
    public static var onMotionFinishedEVENT:TweenEventType = TweenEventType.onMotionFinishedEVENT;
    
    /**
     * Broadcasted to listeners when property value is updated.<br>
     */
    [Event("onMotionChanged")]
    public static var onMotionChangedEVENT:TweenEventType = TweenEventType.onMotionChangedEVENT;
    
    
    //-------------------------------------------------------------------------
    // Private properties
    //-------------------------------------------------------------------------
    
    private var _oEB:EventBroadcaster;

    private var _eOnMotionChangedEvent : TweenEvent;
    private var _eOnMotionFinishedEvent : TweenEvent;
    private var _eOnMotionStartEvent : TweenEvent;
    private var _eOnMotionStopEvent : TweenEvent;
    
    
    //-------------------------------------------------------------------------
    // Public API
    //-------------------------------------------------------------------------
    
    /**
     * /**
     * Constructs a new {@code TweenFPS} instance.
     * 
     * <p>Example
     * <code>
     *   var t:TweenFPS = new TweenMS(mc, '_alpha', 0, 2000, 100);
     * </code>
     * 
     * @param oT     Object which the Tween targets.
     * @param sP     Setter (method or property).
     * @param nE     Ending value of property.
     * @param nMs     Length of time of the motion in milliseconds.
     * @param nS     (optional) Starting value of property.
     * @param fE     (optional) Easing function.
    */
    public function TweenMS(oT, sP, nEnd:Number, nMs:Number, nStart:Number, fE:Function)
    {
        super(oT, sP, nEnd, nMs, nStart, fE);
        _oEB = new EventBroadcaster( this );
        
        _eOnMotionStartEvent = new TweenEvent(onStartEVENT, this);
        _eOnMotionStopEvent = new TweenEvent(onStopEVENT, this);
        _eOnMotionChangedEvent = new TweenEvent(onMotionChangedEVENT, this);
        _eOnMotionFinishedEvent = new TweenEvent(onMotionFinishedEVENT, this);
    }
    
    /**
     * Adds listener for receiving all events.
     * 
     * <p>Example
     * <code>
     *   t.addListener(myListener);
     * </code>
     * 
     * @param oL Listener object which implements {@link ITweenListener} interface.
     */
    public function addListener(oL:ITweenListener) : Void
    {
        _oEB.addListener(oL);
    }
    
    /**
     * Removes listener for receiving all events.
     * 
     * <p>Example
     * <code>
     *   t.removeListener(myListener);
     * </code>
     * 
     * @param oL Listener object which implements {@link ITweenListener} interface.
     */
    public function removeListener(oL:ITweenListener) : Void
    {
        _oEB.removeListener(oL);
    }
    
    /**
     * Adds listener for specifical event.
     * 
     * <p>Example
     * <code>
     *   t.addEventListener( TweenMS.onMotionFinishedEVENT, myListener );
     * </code>
     * 
     * @param t Name of the Event.
     * @param oL Listener object.
     */
    public function addEventListener(e:TweenEventType, oL) : Void
    {
        _oEB.addEventListener.apply(_oEB, arguments);
    }
    
    /**
     * Removes listener for specifical event.
     * 
     * <p>Example
     * <code>
     *   t.removeEventListener( TweenMS.onMotionFinishedEVENT, myListener );
     * </code>
     * 
     * @param t Name of the Event.
     * @param oL Listener object.
     */
    public function removeEventListener(e:TweenEventType, oL) : Void
    {
        _oEB.removeEventListener(e, oL);
    }
    
    /**
     * Starts tweening.
     * 
     * <p>{@link AbstractTween#start} overridding
     */
    public function start() : Void
    {
        execute();
    }
    
    /**
     * Stops tweening.
     * 
     * <p>{@link AbstractTween#stop} overridding
     */
    public function stop() : Void
    {
        super.stop();
        _oEB.broadcastEvent( _eOnMotionStopEvent );
    }
    
    /**
     * Starts tweening
     * 
     * <p>{@link com.bourre.commands.Command} polymorphism.
     * 
     * @see com.bourre.commands.Command
     */
    public function execute( e : IEvent ) : Void
    {
        super.execute();
        _oEB.broadcastEvent( _eOnMotionStartEvent );
    }
    
    /**
     *    Implemented to add tween as listener to another tween.
     */
    public function onMotionFinished() : Void
    {
        execute();
    }
    
    /**
     * Returns the string representation of this instance.
     * @return the string representation of this instance
     */
    public function toString() : String 
    {
        return PixlibStringifier.stringify( this );
    }
    
    
    //-------------------------------------------------------------------------
    // Private implementation
    //-------------------------------------------------------------------------
    
    private function _onMotionEnd() : Void
    {
        super._onMotionEnd();
        _oEB.broadcastEvent( _eOnMotionChangedEvent );
        _oEB.broadcastEvent( _eOnMotionFinishedEvent );
    }
    
    private function _onUpdate() : Void
    {
        super._onUpdate();
        _oEB.broadcastEvent( _eOnMotionChangedEvent );
    }
}

TweenMS extends BasicTweenMS class implementing
Pixlib Event API.

Can use these methods to control Tween event :

Example

var t : TweenMS = new TweenMS(mc, '_alpha', 0, 2000, 100);
t.addListener(this);
t.addEventListener(TweenMS.onMotionFinishedEVENT, this, __onFinish);
t.start();

Summary

Constructor

TweenMS

Class properties

onStartEVENT
onStopEVENT
onMotionFinishedEVENT
onMotionChangedEVENT

Instance properties

Instance properties inherited from BasicTweenMS

_nM _nT

Instance properties inherited from AbstractTween

_bP _fE _isMotionFinished _nE _nRate _nRE _nRS _nS _oBeacon _onUpdate _oSetter

Class methods

Class methods inherited from AbstractTween

noEasing

Instance methods

addListener
removeListener
addEventListener
removeEventListener
start
stop
execute
toString

Instance methods inherited from BasicTweenMS

_isMotionFinished _onUpdate execute resume stop toString

Instance methods inherited from AbstractTween

_buildAccessor _onMotionEnd execute getDuration getEasing getProperty getTarget isPlaying resume setDuration setEasing setEndValue setProperty setStartValue setTarget start stop toString yoyo

Event handlers

onMotionFinished

Event handlers inherited from AbstractTween

onEnterFrame

Constructor

TweenMS

function TweenMS (

nEnd:Number, nMs:Number, nStart:Number, fE:Function)

Constructs a new TweenFPS instance.

Example

var t:TweenFPS = new TweenMS(mc, '_alpha', 0, 2000, 100);

Parameters:

oT :

Object which the Tween targets.

sP :

Setter (method or property).

nE :

Ending value of property.

nMs:

Length of time of the motion in milliseconds.

nS :

(optional) Starting value of property.

fE :

(optional) Easing function.

Class properties

onMotionChangedEVENT

static onMotionChangedEVENT:TweenEventType = TweenEventType.onMotionChangedEVENT

(read,write)

Broadcasted to listeners when property value is updated.

Component metadata:

Event	onMotionChanged

onMotionFinishedEVENT

static onMotionFinishedEVENT:TweenEventType = TweenEventType.onMotionFinishedEVENT

(read,write)

Broadcasted to listeners when tween is finished.

Component metadata:

Event	onMotionFinished

onStartEVENT

static onStartEVENT:TweenEventType = TweenEventType.onStartEVENT

(read,write)

Broadcasted to listeners when tween starts.

Component metadata:

Event	onStart

onStopEVENT

static onStopEVENT:TweenEventType = TweenEventType.onStopEVENT

(read,write)

Broadcasted to listeners when tween stops.

Component metadata:

Event	onStop

Instance methods

addEventListener

function addEventListener (

e:TweenEventType) : Void

Adds listener for specifical event.

Example

t.addEventListener( TweenMS.onMotionFinishedEVENT, myListener );

Parameters:

t :

Name of the Event.

oL:

Listener object.

Specified by:

ITween.addEventListener

addListener

function addListener (

oL:ITweenListener) : Void

Adds listener for receiving all events.

Example

t.addListener(myListener);

Parameters:

oL:

Listener object which implements ITweenListener interface.

Specified by:

ITween.addListener

execute

function execute (

e:IEvent) : Void

Starts tweening

com.bourre.commands.Command polymorphism.

removeEventListener

function removeEventListener (

e:TweenEventType) : Void

Removes listener for specifical event.

Example

t.removeEventListener( TweenMS.onMotionFinishedEVENT, myListener );

Parameters:

t :

Name of the Event.

oL:

Listener object.

Specified by:

ITween.removeEventListener

removeListener

function removeListener (

oL:ITweenListener) : Void

Removes listener for receiving all events.

Example

t.removeListener(myListener);

Parameters:

oL:

Listener object which implements ITweenListener interface.

Specified by:

ITween.removeListener

start

function start (

) : Void

Starts tweening.

AbstractTween.start overridding

Overrides:

AbstractTween.start

Specified by:

IBasicTween.start

stop

function stop (

) : Void

Stops tweening.

AbstractTween.stop overridding

Overrides:

BasicTweenMS.stop

Specified by:

IBasicTween.stop

toString

function toString (

) : String

Returns the string representation of this instance.

Returns:

the string representation of this instance

Overrides:

BasicTweenMS.toString

Event handlers

onMotionFinished

function onMotionFinished (

) : Void

Implemented to add tween as listener to another tween.