+Show TOC
×Hide TOC

Dimension

Kind of class:	public class
Package:	com.bourre.structures
Inherits from:	none
Author:	Cédric Néhémie
Classpath:	com.bourre.structures.Dimension
File last modified:	Friday, 15 February 2008, 21:35:40

► View source

▼ Hide source

/*
 * Copyright the original author or authors.
 * 
 * Licensed under the MOZILLA PUBLIC LICENSE, Version 1.1 (the "License");
 * you may not use this file except in compliance with the License.
 * You may obtain a copy of the License at
 * 
 *      http://www.mozilla.org/MPL/MPL-1.1.html
 * 
 * Unless required by applicable law or agreed to in writing, software
 * distributed under the License is distributed on an "AS IS" BASIS,
 * WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
 * See the License for the specific language governing permissions and
 * limitations under the License.
 */
package com.bourre.structures 
{
    import flash.geom.Point;    
    
    import com.bourre.log.PixlibStringifier;    
    
    /**
     * The Dimension class encapsulates the width and height
     * of an object (in double precision) in a single object.
     * <p>
     * Normally the values of width and height are non-negative
     * integers. The constructors that allow you to create
     * a dimension do not prevent you from setting a negative
     * value for these properties. If the value of width or height
     * is negative, the behavior of some methods defined by other
     * objects is undefined. 
     * </p>
     * @author C√©dric N√©h√©mie
     */
    public class Dimension 
    {
        /**
         * The width dimension, negative values can be used. 
         */
        public var width : Number;
        
        /**
         * The height dimension, negative values can be used. 
         */
        public var height : Number;
        
        /**
         * Constructs a Dimension and initializes it
         * to the specified width and specified height. 
         * 
         * @param    width    specified width
         * @param    height    specified height
         */
        public function Dimension ( width : Number = 0, height : Number = 0 )
        {
            this.width = width;
            this.height = height;
        }
        
        /**
         * Checks whether two dimension objects have equal values.
         * 
         * @param    dimension    the reference object with which to compare.
         * @return    <code>true</code> if this object is the same as the obj
         *             argument, <code>false</code> otherwise.
         */
        public function equals ( dimension : Dimension ) : Boolean
        {
            return (width == dimension.width && height == dimension.height );
        }
        
        /**
         * Sets the size of this Dimension object to the specified size.
         * 
         * @param    dimension    the new size for this Dimension object
         */
        public function setSize ( dimension : Dimension ) : void
        {
            width = dimension.width;
            height = dimension.height;
        }
        /**
         * Sets the size of this Dimension object to the specified width and height.
         * 
         * @param    width    the new width for this Dimension object
         * @param    height    the new height for this Dimension object
         */
        public function setSizeWH ( width : Number, height : Number ) : void
        {
            this.width = width;
            this.height = height;
        }
        /**
         * Returns a copy of this Dimension object.
         * 
         * @return    a copy of this Dimension object
         */
        public function clone() : Dimension
        {
            return new Dimension ( width, height );
        }

        public function scale ( n : Number ) : Dimension
        {
            return new Dimension( width * n, height * n );
        }

        /**
         * Returns a Point object with its x and y sets
         * respectively on width and height of this 
         * Dimension.
         * 
         * @return    a Point object which contains values
         *             of this Dimension
         */
        public function toPoint () : Point
        {
            return new Point( width, height );
        }

        /**
         * Returns the String representation of this object/
         * 
         * @return    the String representation of this object
         */
        public function toString() : String 
        {
            return PixlibStringifier.stringify ( this ) + "[" + width + ", " + height +"]";
        }    
    }
}

The Dimension class encapsulates the width and height
of an object (in double precision) in a single object.

Normally the values of width and height are non-negative
integers. The constructors that allow you to create
a dimension do not prevent you from setting a negative
value for these properties. If the value of width or height
is negative, the behavior of some methods defined by other
objects is undefined.

Summary

Constructor

Dimension (width:Number = 0, height:Number = 0)
- Constructs a Dimension and initializes it

Instance properties

width : Number
- The width dimension, negative values can be used.
height : Number
- The height dimension, negative values can be used.

Instance methods

equals (dimension:Dimension) : Boolean
- Checks whether two dimension objects have equal values.
setSize (dimension:Dimension) : void
- Sets the size of this Dimension object to the specified size.
setSizeWH (width:Number, height:Number) : void
- Sets the size of this Dimension object to the specified width and height.
clone : Dimension
- Returns a copy of this Dimension object.
scale (n:Number) : Dimension
toPoint : Point
- Returns a Point object with its x and y sets
toString : String
- Returns the String representation of this object/

Constructor

Dimension

public function Dimension (

width:Number = 0, height:Number = 0)

Constructs a Dimension and initializes it
to the specified width and specified height.

Parameters:

width :

specified width

height:

specified height

Instance properties

height

public height:Number

(read)

The height dimension, negative values can be used.

width

public width:Number

(read)

The width dimension, negative values can be used.

Instance methods

clone

public function clone (

) : Dimension

Returns a copy of this Dimension object.

Returns:

a copy of this Dimension object

equals

public function equals (

dimension:Dimension) : Boolean

Checks whether two dimension objects have equal values.

Parameters:

dimension:

the reference object with which to compare.

Returns:

true if this object is the same as the obj
argument, false otherwise.

scale

public function scale (

n:Number) : Dimension

setSize

public function setSize (

dimension:Dimension) : void

Sets the size of this Dimension object to the specified size.

Parameters:

dimension:

the new size for this Dimension object

setSizeWH

public function setSizeWH (

width:Number, height:Number) : void

Sets the size of this Dimension object to the specified width and height.

Parameters:

width :

the new width for this Dimension object

height:

the new height for this Dimension object

toPoint

public function toPoint (

) : Point

Returns a Point object with its x and y sets
respectively on width and height of this
Dimension.

Returns:

a Point object which contains values
of this Dimension

toString

public function toString (

) : String

Returns the String representation of this object/

Returns:

the String representation of this object