+Show TOC
×Hide TOC

Logger

Kind of class:	public class
Package:	com.bourre.log
Inherits from:	none
Version:	1.0
Author:	Francis Bourre
Classpath:	com.bourre.log.Logger
File last modified:	Monday, 24 November 2008, 11:36:47

► View source

▼ Hide source

/*
 * Copyright the original author or authors.
 * 
 * Licensed under the MOZILLA PUBLIC LICENSE, Version 1.1 (the "License");
 * you may not use this file except in compliance with the License.
 * You may obtain a copy of the License at
 * 
 *      http://www.mozilla.org/MPL/MPL-1.1.html
 * 
 * Unless required by applicable law or agreed to in writing, software
 * distributed under the License is distributed on an "AS IS" BASIS,
 * WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
 * See the License for the specific language governing permissions and
 * limitations under the License.
 */
package com.bourre.log 
{
    import com.bourre.events.ChannelBroadcaster;
    import com.bourre.events.EventChannel;    

    /**
     * @author Francis Bourre
     * @version 1.0
     */
    public class Logger
    {
        private static var _oI : Logger = null;
        
        private var _oCB : ChannelBroadcaster;
        private var _oLevel : LogLevel;
        
        public function Logger( o : ConstructorAccess )
        {
            setLevel( LogLevel.ALL );
            _oCB = new ChannelBroadcaster();
        }
        
        public static function getInstance() : Logger
        {
            if ( !(Logger._oI is Logger) ) Logger._oI = new Logger( new ConstructorAccess() );
            return Logger._oI;
        }
        
        public function setLevel( level : LogLevel ) : void
        {
            _oLevel = level;
        }
        
        public function getLevel() : LogLevel
        {
            return _oLevel;
        }
        
        public function log( e : LogEvent, oChannel : EventChannel = null ) : Boolean
        {    
            if ( e.level.getLevel() >= _oLevel.getLevel() ) 
            {
                _oCB.broadcastEvent( e, oChannel );
                return true;
            } else
            {
                return false;
            }
        }
        
        public function addLogListener( listener : LogListener, oChannel : EventChannel = null ) : void
        {
            _oCB.addEventListener( LogEvent.onLogEVENT, listener, oChannel );
        }
        
        public function removeLogListener( listener : LogListener, oChannel : EventChannel = null ) : void
        {
            _oCB.removeEventListener( LogEvent.onLogEVENT, listener, oChannel );
        }
        
        public function isRegistered( listener : LogListener, oChannel : EventChannel ) : Boolean
        {
            return _oCB.isRegistered( listener, LogEvent.onLogEVENT, oChannel );
        }
        
        public function hasListener( oChannel : EventChannel = null ) : Boolean
        {
            return _oCB.hasChannelListener( LogEvent.onLogEVENT, oChannel );
        }
        
        public function removeAllListeners() : void
        {
            _oCB.empty();
        }
        
        /**
         * Returns the string representation of this instance.
         * @return the string representation of this instance
         */
        public function toString() : String 
        {
            return PixlibStringifier.stringify( this );
        }
        
        // static methods
        public static function LOG( o : *, level : LogLevel, oChannel : EventChannel = null ) : Boolean
        {
            return Logger.getInstance().log( new LogEvent(level, o ), oChannel );
        }
        
        public static function DEBUG( o : *, oChannel : EventChannel = null ) : Boolean
        {
            return Logger.LOG( o, LogLevel.DEBUG, oChannel  );
        }
        
        public static function INFO( o : *, oChannel : EventChannel = null ) : Boolean
        {
            return Logger.LOG( o, LogLevel.INFO, oChannel  );
        }
        
        public static function WARN( o : *, oChannel : EventChannel = null ) : Boolean
        {
            return Logger.LOG( o, LogLevel.WARN, oChannel );
        }
        
        public static function ERROR( o : *, oChannel : EventChannel = null ) : Boolean
        {
            return Logger.LOG( o, LogLevel.ERROR, oChannel );
        }
        
        public static function FATAL( o : *, oChannel : EventChannel = null ) : Boolean
        {
            return Logger.LOG( o, LogLevel.FATAL, oChannel );
        }
    }
}

internal class ConstructorAccess {}

Summary

Constructor

Logger (o:ConstructorAccess)

Class methods

getInstance : Logger
LOG (o:*, level:LogLevel = null) : Boolean
DEBUG (o:*, oChannel:EventChannel = null) : Boolean
INFO (o:*, oChannel:EventChannel = null) : Boolean
WARN (o:*, oChannel:EventChannel = null) : Boolean
ERROR (o:*, oChannel:EventChannel = null) : Boolean
FATAL (o:*, oChannel:EventChannel = null) : Boolean

Instance methods

setLevel (level:LogLevel) : void
getLevel : LogLevel
log (e:LogEvent = null) : Boolean
addLogListener (listener:LogListener = null) : void
removeLogListener (listener:LogListener = null) : void
isRegistered (listener:LogListener) : Boolean
hasListener (oChannel:EventChannel = null) : Boolean
removeAllListeners : void
toString : String
- Returns the string representation of this instance.

Constructor

Logger

public function Logger (

o:ConstructorAccess)