+Show TOC
×Hide TOC

AbstractIterationCommand

Kind of class:	public class
Package:	com.bourre.commands
Inherits from:	none
Implements:	IterationCommand
Classpath:	com.bourre.commands.AbstractIterationCommand
File last modified:	Tuesday, 22 January 2008, 21:59:34

► View source

▼ Hide source

/*
 * Copyright the original author or authors.
 * 
 * Licensed under the MOZILLA PUBLIC LICENSE, Version 1.1 (the "License");
 * you may not use this file except in compliance with the License.
 * You may obtain a copy of the License at
 * 
 *      http://www.mozilla.org/MPL/MPL-1.1.html
 * 
 * Unless required by applicable law or agreed to in writing, software
 * distributed under the License is distributed on an "AS IS" BASIS,
 * WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
 * See the License for the specific language governing permissions and
 * limitations under the License.
 */
package com.bourre.commands 
{
    import flash.events.Event;
    
    import com.bourre.collection.Iterator;
    import com.bourre.error.UnimplementedVirtualMethodException;
    import com.bourre.log.PixlibDebug;
    import com.bourre.log.PixlibStringifier;        

    /**
     * <code>AbstractIterationCommand</code> provides a skeleton
     * for concret <code>IterationCommand</code> implementations.
     * <p>
     * <code>IterationCommands</code> are not fully stateless as they
     * provide to the <code>LoopCommand</code> which own them the iterator
     * onto which they will work.
     * </p><p>
     * For informations and examples on the behavior of loop commands see the 
     * <a href="../../../../docs/howto/howto-loopcommands.html">How to use LoopCommand
     * and IterationCommand</a> document.
     * </p>
     * @author C√©dric N√©h√©mie
     */
    public class AbstractIterationCommand implements IterationCommand 
    {
        /**
         * A reference to the iterator used by this command
         */
        protected var _oIterator : Iterator;

        /**
         * Initializes this iteration command with the passed-in 
         * <code>Iterator</code>.
         */
        public function AbstractIterationCommand ( i : Iterator )
        {
            _oIterator = i;
        }
        
        /**
         * Override the <code>execute</code> virtual method
         * to create a concret iteration command. Concret command
         * may use the passed-in event as data source for
         * their operation. Used with a <code>LoopCommand</code>
         * the passed-in event is an <code>IterationEvent</code>.
         * 
         * @param    e    event object that will be used as data source by the command 
         * @throws     <code>UnimplementedVirtualMethodException</code> ‚Äî Concret
         *             command doesn't override the <code>execute</code> method
         */
        public function execute( e : Event = null ) : void
        {
            var msg : String = this + ".execute() must be implemented in concrete class.";
            PixlibDebug.ERROR( msg );
            throw( new UnimplementedVirtualMethodException( msg ) );
        }
        
        /**
         * Returns the iterator composed by this command.
         * 
         * @return the iterator composed by this command
         */
        public function iterator () : Iterator
        {
            return _oIterator;
        }
        
        /**
         * Defines which iterator is composed by this command
         * 
         * @param    i iterator instance to be used by this command
         */
        public function setIterator ( i : Iterator ) : void
        {
            _oIterator = i;
        }
    
        /**
         * Returns the string representation of this object.
         * 
         * @return    the string representation of this object
         */
        public function toString() : String 
        {
            return PixlibStringifier.stringify( this );
        }
    }
}

Summary

Constructor

AbstractIterationCommand (i:Iterator)
- Initializes this iteration command with the passed-in

Instance methods

execute (e:Event = null) : void
- Override the execute virtual method
iterator : Iterator
- Returns the iterator composed by this command.
setIterator (i:Iterator) : void
- Defines which iterator is composed by this command
toString : String
- Returns the string representation of this object.

Constructor

AbstractIterationCommand

public function AbstractIterationCommand (

i:Iterator)

Initializes this iteration command with the passed-in

Iterator.

Instance methods

execute

public function execute (

e:Event = null) : void

Override the execute virtual method
to create a concret iteration command. Concret command
may use the passed-in event as data source for
their operation. Used with a LoopCommandthe passed-in event is an IterationEvent.

Parameters:

event object that will be used as data source by the command

Throws:

{VISDOC_LINK_0}UnimplementedVirtualMethodException — Concret
command doesn't override the execute method

iterator

public function iterator (

) : Iterator

Returns the iterator composed by this command.

Returns:

the iterator composed by this command

Specified by:

Iterable.iterator

setIterator

public function setIterator (

i:Iterator) : void

Defines which iterator is composed by this command

Parameters:

iterator instance to be used by this command

toString

public function toString (

) : String

Returns the string representation of this object.

Returns:

the string representation of this object